'ひとりビンゴ
モード=2//test用

//関数設定
「ライバル抜く」を、「?の、?、?を、」で、関数定義。

//母艦の部品作成
	文字サイズ=25
	ラベルを、作る。
	その、可視は、オフ。
	その、テキストは、「55」
	h=(その、高さ)+10
	w=(その、幅)+10

	25回(
		「p{回数}ラベルを、作る。」を、ひまわりする
		その、X=10+(回数-1)%5*w
		その、Y=10+INT((回数-1)/5)*h
	)
	文字サイズは、12
	抽選ボタンを、作る。
		その、位置は、p21ラベルの、下側。
		その、イベントは、抽選イベント。
	(その、右側)に、結果ラベルを、作る。
	その、Y=(その、Y)+5

//ライバルフォームの部品作成
	(p5ラベルの、右側)に、移動
	部品配置間隔は、1
	Aイメージを、作る。
		その、高さは、93
		その、X=(その、X)+5
	A台詞ラベルを、作る。
		その、テキストは、「」
		その、フォントサイズは、10
	Bイメージを、作る。
		その、高さは、93
		その、X=(その、X)+5
		その、Y=(その、Y)+14
	B台詞ラベルを、作る。
		その、テキストは、「」
		その、フォントサイズは、10
		その、Y=(その、Y)+14

母艦は、「ひとりビンゴ」
母艦の、高さは、(抽選ボタンの、Y)+(抽選ボタンの、H)+10
その、スタイルは、ダイアログスタイル。
//その、リサイズは、オフ。
難易度は、「」。
	ペン色は、白色。
	塗り色は、白色。

＊ビンゴ初期化
母艦の、幅は、230//(p5ラベルの、X)+w
その、可視は、オフ。
文字サイズは、10

「モードを選んでね。」を、「ノーマル(ひとり)モード\n予測モード\nライバルモード」の、ボタンで選択。
条件分岐。
「ノーマル(ひとり)モード」の時、モード=0
『予測モード』の時、モード=1
『ライバルモード』の時、モード=2
その他の時、おわり。

//もし、難易度<>「」なら、ダイアログ初期値は、難易度。
「難易度を選んでね。」を、「簡単\n普通\nイライラ」の、ボタンで選択。
難易度は、それ。
条件分岐。
「簡単」の時、n=25
『普通』の時、n=50
『イライラ』の時、n=99
その他の時、おわり。

a=「」
n回(
	もし、回数<10なら、回数を、全角変換。
	違えば、それ=回数
	a=「{a}{それ}\n」
)

aを、配列シャッフル。
a=それ
25回、「p{回数}ラベルの、フォント色は、黒色。p{回数}ラベルは、『{a#(回数-1)}』。」を、ひまわりする。

p13ラベルの、テキストは、「♪」
その、フォント色は、青色。

aを、配列シャッフル。
a=それ

n=0
リーチ=0
ビンゴ=0
k=「0,0,0,0,0\n0,0,0,0,0\n0,0,1,0,0\n0,0,0,0,0\n0,0,0,0,0」

モードで、条件分岐。
1の時、予測モード。
2の時、ライバルモード。

結果ラベルは、「0回目 リーチ 0」
母艦の、可視は、1
母艦浮上。//何度『母艦浮上』しても大丈夫らしい。

待機。

＊抽選イベント
q=0
25回(
	もし、回数=13ならば、続ける。
	「もし、(p{回数}ラベル=(a#n))ならば、q=1」を、ひまわりする。
	もし、q=1ならば、(
		「p{回数}ラベル=『♪』
		p{回数}ラベルの、フォント色は、青色。
		k#{(回数-1)%5}#{INT((回数-1)/5)}=1」を、ひまわりする。
		もし、n>3なら、確認イベント。
		抜ける。
	)
)

n=n+1
結果ラベルは、「{n}回目 リーチ {リーチ}」

n=n-1
もし、モード=2なら、ライバル抽選。
n=n+1

戻る。

＊確認イベント
	リーチ=0
	ビンゴ=0

	//縦の確認
	5回(
	kの、(回数-1)列目の、表合計。
	条件分岐
	4の時、リーチ=リーチ+1
	5の時、ビンゴ=ビンゴ+1
	)
	
	//横の確認
	5回(
	「k#{回数-1}を、『,』で、区切る。」を、ひまわりする。
	配列合計値。
	条件分岐
	4の時、リーチ=リーチ+1
	5の時、ビンゴ=ビンゴ+1
	)
	
	//斜めの確認
	b=0
	5回、bに、(k#(回数-1)#(回数-1))を、足す。
	bで、条件分岐
	4の時、リーチ=リーチ+1
	5の時、ビンゴ=ビンゴ+1
	
	b=0
	5回、bに、(k#(回数-1)#(5-回数))を、足す。
	bで、条件分岐
	4の時、リーチ=リーチ+1
	5の時、ビンゴ=ビンゴ+1
	
	もし、ビンゴ>0ならば、ビンゴイベントに、飛ぶ。
戻る。

＊ビンゴイベント
もし、モード=2なら、ライバルビンゴ。

ビンゴで、条件分岐。
1の時、「やったね！ビンゴ！！」と、言う。
2の時、「Wonderful！！ダブルビンゴ！！」と、言う。
3の時、「奇跡のトリプルビンゴ！！！」と、言う。

もし、モード=1なら、予測ビンゴに、飛ぶ。

もし、モード=0なら、(
	難易度で、条件分岐。
	「簡単」の時、(
		nで、条件分岐。
		5以下の時、「すごいすごいすご〜い！！\n今日はめちゃめちゃラッキーかも♪」と、言う。
		15以下の時、「なかなか運がいいかも。」と、言う。
		その他の時、「遊んでくれてどうもありがとう。」と、言う。
	)
	「イライラ」の時、(
		nで、条件分岐。
		20以下の時、「すごいすごいすご〜い！！\n今日はめちゃめちゃラッキーかも♪」と、言う。
		35以下の時、「なかなか運がいいかも。」と、言う。
		65以下の時、「遊んでくれてどうもありがとう。」と、言う。
		その他の時、「ずいぶんかかっちゃったね…\nお疲れ様でした。」と、言う。
	)
	その他の時、(
		nで、条件分岐。
		10以下の時、「すごいすごいすご〜い！！\n今日はめちゃめちゃラッキーかも♪」と、言う。
		35以下の時、「なかなか運がいいかも。」と、言う。
		その他の時、「遊んでくれてどうもありがとう。」と、言う。
	)
)

「もう一度遊びますか？」と、二択。
もし、それ=1なら、ビンゴ初期化に、飛ぶ。

おわり。

＊予測モード
	モード=1

	難易度で、条件分岐。
	「簡単」の時、b=25
	「イライラ」の時、b=99
	その他の時、b=50
	//回数制限
	q=0
	(q=0)で、ループ(
		「何回でビンゴになると思いますか？\n5〜{b}の間で指定してください」と、尋ねる。
		もし、それ=ダイアログキャンセルの値なら、おわり。
		もし、(それ>=5)かつ(それ<=b)なら、(
			q=それ。抜ける。
		)
	)
	

	予測回数=それ+0
戻る。

＊予測ビンゴ

ABS(予測回数-n)

難易度で、条件分岐。
「簡単」の時、(
条件分岐。
	0の時、「予測と同じ！！\n実は予知能力者？！」と、言う。
	5以下の時、「惜しいっあと{それ}回でピタリ賞！」と、言う。
	10以下の時、「大体ぴったり？」と、言う。
	20以下の時、「{それ}回違いですか。ふむー…」と、言う。
	その他の時、「まさか{n}回とは。\nずいぶん外れましたなぁ。」と、言う。
)
「イライラ」の時、(
条件分岐。
	0の時、「すごい！予測と同じ！！実は予知能力者？！」と、言う。
	5以下の時、「惜しいっあと{それ}回でピタリ賞！」と、言う。
	10以下の時、「{n}回かぁ。大体ぴったり？」と、言う。
	20以下の時、「予測と{それ}回違っちゃいましたね〜。\nこんなものかな？」と、言う。
	40以下の時、「{それ}回違いですか。あらあら…」と、言う。
	70以下の時、「まさか{n}回とは。\nずいぶん外れましたなぁ。」と、言う。
	その他の時、「大ハズレ〜これだけ外すのは逆にレアかも☆」と、言う。
)
その他の時、(
	条件分岐。
	0の時、「すごい！予測と同じ！！実は予知能力者？！」と、言う。
	5以下の時、「惜しいっあと{それ}回でピタリ賞！」と、言う。
	10以下の時、「大体ぴったり？」と、言う。
	20以下の時、「予測と{それ}回違っちゃいましたね〜。\nこんなものかな？」と、言う。
	35以下の時、「{それ}回違いですか。あらあら…」と、言う。
	その他の時、「まさか{n}回とは。\nずいぶん外れましたなぁ。」と、言う。
)
「もう一度遊びますか？」と、二択。
もし、それ=1なら、ビンゴ初期化に、飛ぶ。
おわり。

＊ライバルモード
//A氏とB氏の二人がライバル☆
「A\nB」を、反復(
	変数名は、それ。
	aを、配列シャッフル。
	25個目の、「\n」を、"\n\n"に、単置換
	1番目の、段落を切り出す。
'　	「\n」を、「,」に、置換。
'	『s#(([\d０-９]*,){5})#$1\n#g』で、正規表現置換。
'	『s#(.*),#$1#mg』で、正規表現置換。
	トリム。
	「{変数名}の、『p』=それ。\n{変数名}の、『k』=k
	{変数名}の、『ビンゴ』=0。\n{変数名}の、『リーチ』=0
	{変数名}イメージの、画像は、『』
	{変数名}台詞ラベルは、『』」を、ひまわりする。
)

(Aの、『p』)を、反復(
	Aイメージの、(((回数-1)%5*20),INT((回数-1)/5)*20)へ、それと、文字表示
)
(Bの、『p』)を、反復(
	Bイメージの、(((回数-1)%5*20),INT((回数-1)/5)*20)へ、それと、文字表示
)

「A」の、2、2を、ライバル抜く。
「B」の、2、2を、ライバル抜く。

母艦の、幅は、340
戻る。

＊ライバル抽選
「A\nB」を、反復(
	q=0。
	変数名は、それ。
	「({変数名}の、『p』)を、『,』で、区切る。」を、ひまわりする。
	反復(もし、(それ=a#n)なら、(q=1。抜ける。))
	もし、q=0なら、続ける。

	q=回数-1
	「それ={変数名}の、『k』
	それ#{q%5}#{INT(q/5)}=1
	{変数名}の、『k』=それ。」を、ひまわりする。
	変数名の、(q%5)、(INT(q/5))を、ライバル抜く。
	
	もし、n>3なら、ライバル確認。
)

もし、(Aの、「ビンゴ」>0)または(Bの、「ビンゴ」>0)なら、ビンゴイベント。
もし、(Aの、「リーチ」>0)または(Bの、「リーチ」>0)なら、ライバルリーチ。

戻る。

＊ライバル確認
	「{変数名}の、『ビンゴ』=0;\n{変数名}の、『リーチ』=0」を、ひまわりする。
	//縦
	5回(
		「({変数名}の、『k』)の、(回数-1)列目の、表合計。」を、ひまわりする。
		条件分岐。
		4の時、(「{変数名}の、『リーチ』=({変数名}の、『リーチ』)+1」を、ひまわりする。)
		5の時、(「{変数名}の、『ビンゴ』=({変数名}の、『ビンゴ』)+1」を、ひまわりする。)
	)
	//横
	5回(
		「それ={変数名}の、『k』」を、ひまわりする。
		(それ#(回数-1))を、『,』で、区切る。
		配列合計値。
		条件分岐。
		4の時、(「{変数名}の、『リーチ』=({変数名}の、『リーチ』)+1」を、ひまわりする。)
		5の時、(「{変数名}の、『ビンゴ』=({変数名}の、『ビンゴ』)+1」を、ひまわりする。)
	)
	//斜めの確認
	「それ={変数名}の、『k』」を、ひまわりする。
	b=0
	5回、bに、(それ#(回数-1)#(回数-1))を、足す。
	bで、条件分岐
	4の時、(「{変数名}の、『リーチ』=({変数名}の、『リーチ』)+1」を、ひまわりする。)
	5の時、(「{変数名}の、『ビンゴ』=({変数名}の、『ビンゴ』)+1」を、ひまわりする。)
	
	b=0
	5回、bに、(それ#(回数-1)#(5-回数))を、足す。
	bで、条件分岐
	4の時、(「{変数名}の、『リーチ』=({変数名}の、『リーチ』)+1」を、ひまわりする。)
	5の時、(「{変数名}の、『ビンゴ』=({変数名}の、『ビンゴ』)+1」を、ひまわりする。)
戻る。

＊ライバル抜く
	引数取得。
	変数名は、それ#0
	XX=(それ#1)*20
	YY=(それ#2)*20
	
	文字色は、赤色。
	「{変数名}イメージの、(XX,YY)から、(XX+19,YY+19)へ、四角形描画。
	{変数名}イメージの、(XX,YY)へ、『★』と、文字表示」を、ひまわりする。
	文字色は、黒色。
戻る。

＊ライバルビンゴ
	(Aの、「ビンゴ」)で、条件分岐。
	1の時、A台詞ラベル=「よっしゃ〜っ！\nビンゴ！！」。
	2の時、A台詞ラベル=「イエイ！！\nダブルビンゴ！」。
	3の時、A台詞ラベル=「トリプルビンゴ！\nオレ最強♪」。
	その他の時、A台詞ラベル=「ちっくしょ〜っ\nもう一回だっっ」。

	(Bの、「ビンゴ」)で、条件分岐。
	1の時、B台詞ラベル=「えへへっ\n一番乗り♪」。
	2の時、B台詞ラベル=「みてみてっ！\n２つビンゴだよ！！」。
	3の時、B台詞ラベル=「ビンゴが3つ！！\nすごいでしょ〜♪」。
	その他の時、B台詞ラベル=「うわーん。\n負けちゃったよぅ」。

	もし、(Aの、「ビンゴ」>0)なら、「A君の勝ちです。」と、言う。
	もし、(Bの、「ビンゴ」>0)なら、「Bちゃんの勝ちです。」と、言う。
	
戻る。

＊ライバルリーチ
	(Aの、「リーチ」)で、条件分岐。
	0の時、()
	1の時、A台詞ラベル=「よしっリーチ！」。
	2の時、A台詞ラベル=「ダブルリーチ！」。
	3の時、A台詞ラベル=「トリプルリーチ！」。
	6以下の時、A台詞ラベル=「{Aの、『リーチ』}リーチかぁ。\nうーん…。」。
	その他の時、A台詞ラベル=「またかよっ\n次こそビンゴッ」。

	(Bの、「リーチ」)で、条件分岐。
	0の時、()
	1の時、B台詞ラベル=「リーチだよ♪」。
	3以下の時、B台詞ラベル=「リーチ{Bの、『リーチ』}こ♪」。
	6以下の時、B台詞ラベル=「リーチ{Bの、『リーチ』}こ〜\nむー。」。
	その他の時、B台詞ラベル=「またリーチだよぅ\nビンゴにな〜れっ」。
	
戻る。