'スキン作成支援セット
バージョン=「1.00」
母艦は、「スキン作成支援」
変数設定
利用ファイルの有無確認
メニューの設定
部品の作成
母艦の設定
設定読み込み
//リサイズイベント
母艦浮上
待機。
＊設定読み込み
戻るフラグ=1
iniファイルを、開く。
作者名は、それ#0
メアドは、それ#1
アドレスは、それ#2
対応画像形式は、それ#3
対応圧縮形式は、それ#4
名前エディタ=それ#0
メアドエディタ=それ#1
アドレスエディタ=それ#2
基本フォルダエディタ=それ#5
文字サンプルラベルの、背景色=それ#6
背景サンプルラベルの、背景色=それ#7
画像ファイルエディタ=それ#9
配置ラジオ=それ#10
画像ファイルを使用チェック=それ#8
画像ファイルチェックイベント
戻るフラグ=0
拡張子コンボイベント
母艦の、背景色は、背景サンプルラベルの、背景色
「ラベル\nタブラベル\nメニューラベル」を、反復(
「{それ}の、フォント色は、文字サンプルラベルの、背景色」を、ひまわりする。
)
戻る。
＊母艦背景
母艦の、背景色は、背景サンプルラベルの、背景色
もし、画像ファイルを使用チェック=1、かつ、画像ファイルエディタ<>「」なら、(
画像ファイルエディタが、ファイルか。
もし、それ=0なら、戻る。
ダミーイメージは、画像ファイルエディタ。
a=ダミーイメージの、幅
b=ダミーイメージの、高さ
もし、配置ラジオ=0なら、(
c=0
d=0
「d<{母艦の、高さ}」で、ループ(
ダミーイメージを、母艦の、(c,d)に、イメージコピー。
c=c+a
もし、(c>(母艦の、幅))なら、(
c=0
d=d+b
)
)
)
違えば、(
c=INT(((母艦の、幅)-a)/2)
d=INT(((母艦の、高さ)-b)/2)
ダミーイメージを、母艦の、(c,d)に、イメージコピー。
)
)
戻る。
＊設定書き込み
「{名前エディタ}\n{メアドエディタ}\n{アドレスエディタ}
{対応画像形式}\n{対応圧縮形式}\n{基本フォルダエディタ}
{文字サンプルラベルの、背景色}\n{背景サンプルラベルの、背景色}
{画像ファイルを使用チェック}\n{画像ファイルエディタ}\n{配置ラジオ}」を、
iniファイルへ、保存
戻る。
＊変数設定
メニューグリッド初期アイテム=「該当個所,ファイル名
1:新規
2:ファイルを開く
3:上書き保存
4:元に戻す
5:切り取り
6:コピー
7:貼り付け
8:実行
9:停止
10:一時停止」
タブグリッド初期アイテム=「該当個所,ファイル名
1:group close
2:group open
3:sub-group close
4: open
5:command icon
6:variable icon
7:gui object close
8:gui object open
9:gui read write
10:gui read
11:gui write
12:macro icon」
ダイアログキャンセルの値=「{CHR(1)}」
インストーラ雛形=『「インストールします。\nよろしいですか？」と、二択。
もし、それ<>1なら、おわり。
ランタイムのパス&「skin\\スキン名\\」へ、フォルダ作成。
「[作者]
名前=作者名
メール=メアド
WEB=アドレス
[スキン]
名前=スキン名
説明=スキン説明
[メニュー]
size=メニュー幅
[タブ]
size=タブ幅」を、ランタイムのパス&「skin\\スキン名\\info.ini」へ、保存。
「menuファイル」を、BASE64デコード。
ランタイムのパス&「skin\\スキン名\\menu.bmp」へ、保存。
「tabファイル」を、BASE64デコード。
ランタイムのパス&「skin\\スキン名\\tab.bmp」へ、保存。
「インストールが完了しました。」と、言う。
母艦の、X=デスクトップの幅+1
おわり。
母艦浮上。』
作成ボタンヘルプ=「スキンファイルを作成します。」
メニュー追加ボタンヘルプ=「選択中の項目にダイアログでファイルを設定します。」
メニュー削除ボタンヘルプ=「選択中の項目を削除します。」
メニュー上へボタンヘルプ=「２番目以降を選択中の時、選択項目を１つ上の項目と交換します。」
メニュー下へボタンヘルプ=「１番下以外を選択中の時、選択項目を１つ下の項目と交換します。」
メニュークリアボタンヘルプ=「確認後、上のグリッドのアイテムを初期化します。」
メニューグリッドヘルプ=「ファイルをドロップすると選択項目以降のアイテムが設定されます。」
タブ追加ボタンヘルプ=「選択中の項目にダイアログでファイルを設定します。」
タブ削除ボタンヘルプ=「選択中の項目を削除します。」
タブ上へボタンヘルプ=「２番目以降を選択中の時、選択項目を１つ上の項目と交換します。」
タブ下へボタンヘルプ=「１番下以外を選択中の時、選択項目を１つ下の項目と交換します。」
タブクリアボタンヘルプ=「確認後、下のグリッドのアイテムを初期化します。」
タブグリッドヘルプ=「ファイルをドロップすると選択項目以降のアイテムが設定されます。」
ステータスエディタヘルプ=「各部品にマウスを合わせると簡易ヘルプを表示します。」
スクロールヘルプ=「ファイル名が設定されている項目を選択するとプレビューを表示します。」
イメージヘルプ=「ファイル名が設定されている項目を選択するとプレビューを表示します。」
高さラベルヘルプ=「選択ファイルの幅と高さを表示します。高さが32以上の場合、スキンを作成できません。」
拡張子コンボヘルプ=「形式を指定する,ファイルの種類を,選択します。」
拡張子リストヘルプ=「Deleteキーを押すと,選択項目が,削除されます。」
拡張子エディタヘルプ=「追加したい拡張子を,記入してください。,Enterで追加します。」
拡張子追加ボタンヘルプ=「エディタに書かれた,拡張子をリストの,一番下に追加します。」
拡張子削除ボタンヘルプ=「選択項目を,削除します。」
拡張子初期化ボタンヘルプ=「コンボで選んだ,種類の設定を,初期化します。」
初期画像形式=「bmp,jpg,png,ico,」
初期圧縮形式=「lzh,」
作成エラー=「
未対応のファイルが含まれています。
画像ファイルが指定されていません。
画像ファイルが大きすぎます。32*32以下のファイルを指定してください。
画像の高さが統一されていません。
画像の幅が足りません。ファイルの数が足りない可能性があります。
画像の幅が多すぎます。高さと幅が同じファイルを使用してください。」
戻る。
＊母艦の設定
母艦の、変更した時は、リサイズイベント
母艦の、背景色は、灰色
その、マウス動かした時は、ステータスエディタは、「」
戻る。
＊メニューの設定
ファイルメニューを、作る。
その、テキストは、「ファイル(F)」。
ファイルメニューに、新規メニューを、メニュー追加。
その、テキストは、「新規(N)」。
その、ショートカットキーは、「Ctrl+N」。
その、イベントは、新規イベント。
ファイルメニューに、終了メニューを、メニュー追加。
その、テキストは、「終了(W)」。
その、ショートカットキーは、「Ctrl+W」。
その、イベントは、終わり。
設定メニューを、作る。
その、テキストは、「設定(S)」。
その、イベントは、設定メニューイベント。
ヘルプメニューを、作る。
その、テキストは、「ヘルプ(H)」。
ヘルプメニューに、使い方メニューを、メニュー追加。
その、テキストは、「使い方等(H)」。
その、ショートカットキーは、「F1」。
その、イベントは、ヘルプメニューイベント。
ヘルプメニューに、バージョン情報メニューを、メニュー追加。
その、テキストは、「バージョン情報(A)」。
その、イベントは、「スキン作成支援キット\n ver.{バージョン}\n\n by yuk」と、言う。
戻る。
＊部品の作成
ラベルを、作る。
その、テキストは、「下のグリッドに埋め込みたいファイルをドロップしてください。」
(その、右側)に、作成ボタンを、作る。
その、イベントは、作成イベント
その、Y=(その、Y)-5
その、マウス動かした時は、簡易ヘルプイベント。
「メニュー\nタブ」を、反復(
文字サイズは、12
「{それ}ラベルを、作る。」を、ひまわりする。
文字サイズは、10
「(その、右側)に、{それ}追加ボタンを、作る。」を、ひまわりする。
その、イベントは、アイテム追加。
その、テキストは、「＋」
その、幅は、その、高さ。
その、Y=(その、Y)-5
その、X=82
その、マウス動かした時は、簡易ヘルプイベント。
「(その、右側)に、{それ}削除ボタンを、作る。」を、ひまわりする。
その、イベントは、アイテム削除。
その、テキストは、「−」
その、幅は、その、高さ。
その、マウス動かした時は、簡易ヘルプイベント。
「(その、右側)に、{それ}上へボタンを、作る。」を、ひまわりする。
その、イベントは、アイテム上へ。
その、テキストは、「↑」
その、幅は、その、高さ。
その、マウス動かした時は、簡易ヘルプイベント。
「(その、右側)に、{それ}下へボタンを、作る。」を、ひまわりする。
その、イベントは、アイテム下へ。
その、テキストは、「↓」
その、幅は、その、高さ。
その、マウス動かした時は、簡易ヘルプイベント。
「(その、右側)に、{それ}クリアボタンを、作る。」を、ひまわりする。
その、イベントは、アイテムクリア。
その、テキストは、「クリア」
その、幅は、(その、高さ)*3。
その、マウス動かした時は、簡易ヘルプイベント。
「{それ}グリッドを、作る。
その、アイテムは、{それ}グリッド初期アイテム」を、ひまわりする。
その、ファイルドロップは、オン
その、ファイルドロップした時は、グリッドイベント。
その、クリックした時は、アイテム選択。
その、編集は、オフ。
その、マウス動かした時は、簡易ヘルプイベント。
)
メニューラベルは、「menu.bmp」
タブラベルは、「tab.bmp」
メニューグリッドの、Yは、(メニュー上へボタンの、Y)+(メニュー上へボタンの、高さ)+5。
ステータスエディタを、作る。
その、X=0
その、編集は、オフ。
その、背景色は、ウインドウ色
その、マウス動かした時は、簡易ヘルプイベント。
イメージを、作る。
その、位置は、(0,0)
その、サイズは、(0,0,32,32)
その、マウス動かした時は、簡易ヘルプイベント。
高さラベルを、作る。
その、テキストは、「」
その、マウス動かした時は、簡易ヘルプイベント。
スクロールを、作る。
その、アイテムは、「イメージ\n高さラベル」。
その、位置は、(0,0)
その、マウス動かした時は、簡易ヘルプイベント。
プレビューフォームを、作る。
その、アイテムは、「スクロール」。
その、スタイルは、ダイアログスタイル。
その、高さは、80
その、幅は、80
その、背景色は、灰色。
その、X=(母艦の、X)+(母艦の、W)-90
その、Y=(母艦の、Y)+40
スクロールの、幅は、プレビューフォームの、幅。
その、高さは、プレビューフォームの、高さ。
プレビューフォームを、最前面。
ダミーイメージを、作る。
その、可視は、オフ。
＊設定フォームの作成
(10,10)に、移動。
「名前\nメアド\nアドレス」を、
反復(
「{それ}ラベルを、作る。」を、ひまわりする。
(その、右側)に、それ&エディタを、作る。
その、Y=(その、Y)-3
その、X=120
その、W=150
)
名前ラベルは、「作者名」
メアドラベルは、「メールアドレス」
アドレスラベルは、「Webアドレス」
画像の基本フォルダラベルを、作る。
基本フォルダエディタを、作る。
その、幅は、200
(その、右側)に、基本フォルダボタンを、作る。
その、テキストは、「選択」
その、イベントは、基本フォルダ設定イベント。
その、幅は、50
その、Y=(その、Y)-2
(10,10)に、移動。
拡張子コンボを、作る。
その、アイテムは、「利用可能な画像形式\n利用可能な圧縮形式」
その、値は、0
その、編集は、オフ。
その、イベントは、拡張子コンボイベント
拡張子リストを、作る。
その、高さは、(その、高さ)+17
その、キー押した時は、もし、押されたキー=46{Delete}なら、拡張子削除イベント
その、マウス動かした時は、拡張子ヘルプイベント
(その、右側)に、拡張子エディタを、作る。
その、幅は、80
その、マウス動かした時は、拡張子ヘルプイベント
その、キー押した時は、もし、押されたキー=13なら、拡張子追加イベント
(その、右側)に、拡張子追加ボタンを、作る。
その、テキストは、「＋」
その、幅は、20
その、高さは、拡張子エディタの、高さ。
その、マウス動かした時は、拡張子ヘルプイベント
その、イベントは、拡張子追加イベント
(その、右側)に、拡張子削除ボタンを、作る。
その、テキストは、「−」
その、幅は、20
その、高さは、拡張子エディタの、高さ。
その、マウス動かした時は、拡張子ヘルプイベント
その、イベントは、拡張子削除イベント
(拡張子エディタの、下側)に、拡張子初期化ボタンを、作る。
その、テキストは、「初期化」
その、マウス動かした時は、拡張子ヘルプイベント
その、イベントは、拡張子初期化イベント
(その、下側)に、拡張子ヘルプラベルを、作る。
その、テキストは、「」
(5,6)に、移動。
「文字\n背景」を、反復(
「{それ}ラベルを、作る。」を、ひまわりする。
その、Y=(その、Y)+4
その、X=(その、X)+5
(その、右側)に、それ&サンプルラベルを、作る。
その、透過処理は、オフ。
その、テキストは、「」
その、幅は、30
(その、右側)に、それ&選択ボタンを、作る。
その、テキストは、「選択」
その、幅は、50
その、高さは、拡張子エディタの、高さ。
その、Y=(その、Y)-4
その、イベントは、色選択イベント
(その、右側)に、移動。
)
(文字ラベルの、下側)に、移動。
画像ファイルを使用チェックを、作る。
その、幅は、140
その、Y=(その、Y)+10
その、イベントは、画像ファイルチェックイベント
画像ファイルエディタを、作る。
その、X=20
その、幅は、180
その、Y=(その、Y)+10
(その、右側)に、画像選択ボタンを、作る。
その、テキストは、「選択」
その、幅は、50
その、Y=(その、Y)-2
その、イベントは、画像選択イベント
配置ラジオを、作る。
その、アイテムは、「画像を敷き詰める\n画像を中央に表示」
その、高さは、65
その、X=20
その、Y=(その、Y)-10
その、幅は、240
その、値は、0
(10,10)に、移動。
タブページを、作る。
その、テキストは、「基本設定\n拡張子設定\nインターフェイス」
その、アイテムは、「名前ラベル\nメアドラベル\nアドレスラベル\n画像の基本フォルダラベル\n名前エディタ\nメアドエディタ\nアドレスエディタ\n基本フォルダエディタ\n基本フォルダボタン\n」
その、値は、1
その、アイテムは、「拡張子ヘルプラベル\n拡張子コンボ\n拡張子リスト\n拡張子エディタ\n拡張子追加ボタン\n拡張子削除ボタン\n拡張子初期化ボタン\n」
その、値は、2
その、アイテムは、「文字ラベル\n文字サンプルラベル\n背景ラベル\n背景サンプルラベル\n文字選択ボタン\n背景選択ボタン\n画像ファイルを使用チェック\n画像ファイルエディタ\n画像選択ボタン\n配置ラジオ\n」
その、値は、0
設定OKボタンを、作る。
その、テキストは、「決定」
その、イベントは、設定決定イベント
(その、右側)に、設定キャンセルボタンを、作る。
その、テキストは、「キャンセル」
その、イベントは、設定決定イベント
設定フォームを、作る。
その、可視は、オフ。
その、アイテムは、「タブページ\n設定OKボタン\n設定キャンセルボタン\n」
その、スタイルは、ダイアログスタイル
その、高さは、(その、高さ)+30
その、背景色は、ウインドウ色
設定フォームを、最前面。
戻る。
＊リサイズイベント
もし、戻るフラグ=1なら、戻る。
戻るフラグ=1
もし、((母艦の、幅)<565)なら、母艦の、幅=565
もし、((母艦の、高さ)<250)なら、母艦の、高さ=250
戻るフラグ=0
ステータスエディタの、Y=(母艦の、高さ)-(ステータスエディタの、高さ)
その、幅は、母艦の、幅
メニューグリッドの、高さは、INT(((ステータスエディタの、Y)-(メニューグリッドの、Y)-45)/2)
その、幅は、母艦の、幅-20
タブラベルの、位置は、メニューグリッドの、下側。
その、Y=(その、Y)+5
「追加\n削除\n上へ\n下へ\nクリア」を、
反復(「タブ{それ}ボタンの、Yは、(タブラベルの、Y)-5」を、ひまわりする。)
タブグリッドの、Yは、(タブ上へボタンの、Y)+(タブ上へボタンの、高さ)+5。
その、高さは、メニューグリッドの、高さ。
その、幅は、母艦の、幅-20
母艦背景
戻る。
＊利用ファイルの有無確認
ヘルプファイル=「{母艦のパス}help\\help.html」
ヘルプファイルが、存在するか。
もし、それ=0なら、ヘルプファイルの作成
iniファイル=「{母艦のパス}skin.ini」
iniファイルが、存在するか。
もし、それ=1なら、戻る。
ダイアログIMEの状態=1
それ=「」
ダイアログキャンセルの値=「{CHR(1)}」
『それ=「」』で、ループ(「あなたの名前を入力してください」と、尋ねる。)
もし、それ=ダイアログキャンセルの値なら、おわり。
nameは、それ。
ダイアログIMEの状態=0
「メールアドレスを入力してください」と、尋ねる。
もし、それ=ダイアログキャンセルの値なら、おわり。
メアドは、それ。
「サイトアドレスを入力してください」と、尋ねる。
もし、それ=ダイアログキャンセルの値なら、おわり。
iniファイルに、「{name}\n{メアド}\n{それ}\n{初期画像形式}
{初期圧縮形式}\n{母艦のパス}\n{黒色}\n{灰色}\n0\n\n0」を、保存。
戻る。
＊作成イベント
ステータスエディタは、『結合チェック開始』
「メニュー\nタブ」を、反復(
a=0
b=「」
c=それ
d=0
e=0
「{それ}グリッド」を、その単語に特定。
(その、アイテム)の、1列目を、表列コピー。0行目を、行削除
反復(
もし、それ=「」なら、続ける。
ファイル名は、それ。
ファイル名を切り出す。
拡張子を切り出す。
「.」を、「」に、置換。
対応画像形式の中で、それが、何文字目。
もし、それ<1なら、(a=1。抜ける。)
イメージは、ファイル名。
b=b&「{イメージの、高さ}\n」。
e=e+(イメージの、幅)
)
もし、b=「」なら、a=2。
もし、b>32なら、a=3。
もし、a>0なら、抜ける。
//高さチェック
bの、0列目をキーに、表重複項目削除。
トリム。
b=それ
行数
もし、それ>1なら、(a=4。抜ける)
//幅チェック
「それ={c}グリッドの、アイテム。」を、ひまわりする。
要素数
もし、(e<>(それ-2)*b)なら、(
もし、(e<(それ-2)*b)なら、a=5。
違えば、a=6
抜ける
)
)
「c={c}ラベル」を、ひまわりする。
もし、a>0なら、(
戻るフラグ=1
ステータスエディタは、「結合失敗({c})：{作成エラー#a}」
描画処理反映
戻るフラグ=0
戻る。
)
ステータスエディタは、『結合開始』
「メニュー\nタブ」を、反復(
c=それ
「{それ}グリッド」を、その単語に特定。
それ=その、アイテム
行数
d=それ-2
(その、アイテム)の、1列目を、表列コピー。0行目を、行削除
イメージは、それ#0
b=その、幅
ダミーイメージの、幅は、b*d
その、高さは、イメージの、高さ
e=0
反復(
もし、それ=「」なら、続ける。
イメージは、それ。
イメージを、ダミーイメージの、((b*e),0)に、イメージコピー。
e=e+1
)
「それ={c}ラベル」を、ひまわりする。
トリム。
母艦のパス&それに、ダミーイメージを、イメージ保存。
)
ステータスエディタは、『結合完了』
それ=「」
『それ=「」』で、ループ(「スキン名は？」と、尋ねる。)
もし、それ=ダイアログキャンセルの値なら、戻る。
スキン名は、それ。
「簡単な説明を記入してください。」と、尋ねる。
もし、それ=ダイアログキャンセルの値なら、戻る。
説明は、それ。
ステータスエディタは、『インストーラ作成中』
ダミーイメージは、母艦のパス&メニューラベル
a=その、高さ
ダミーイメージは、母艦のパス&タブラベル
b=その、高さ
母艦のパス&「menu.bmp」を、開く。
BASE64エンコード。
128バイトで、行揃え
c=それ
母艦のパス&「tab.bmp」を、開く。
BASE64エンコード。
128バイトで、行揃え
d=それ
インストーラ雛形の、『作者名』を、作者名に、置換。
『メアド』を、メアドに、置換。
「アドレス」を、アドレスに、置換。
『スキン名』を、スキン名に、置換。
『スキン説明』を、説明に、置換。
「メニュー幅」を、aに、置換。
「タブ幅」を、bに、置換。
「menuファイル」を、cに、置換。
「tabファイル」を、dに、置換。
a=それ。
ダイアログ初期値=スキン名
「ひまわりファイル(*.hmw)|*.hmw」の、書込ファイル選択。
もし、それ=ダイアログキャンセルの値なら、戻る。
aを、それに、保存。
b=それ
「圧縮しますか？」と、二択。
もし、それ=1なら、(
ダイアログ初期値=スキン名
「lzhファイル(*.lzh)|*.lzh|zipファイル(*.zip)|*.zip|全てのファイル(*.*)|*.*」の、書込ファイル選択。
もし、それ=ダイアログキャンセルの値なら、戻る。
bを、それへ、圧縮
)
「a\nb\nc\nd\ne」を、反復(「{それ}=『』」を、ひまわりする。)
ステータスエディタは、「作成完了」
戻る。
＊アイテム追加
(イベントオブジェクトの、名前)の、『追加ボタン』を、グリッドに、置換。
その単語に特定。
要素数((その、アイテム))
もし、((その、値)<0)または((その、値)>(それ-2))なら、戻る。
もし、基本フォルダエディタ<>「」なら、作業フォルダは、基本フォルダエディタ。
「ICOファイル(*.ico)|*.ico|BMPファイル(*.bmp)|*.bmp|JPEGファイル(*.jpg)|*.jpg|PNGファイル|*.png|全てのファイル(*.*)|*.*」の、読込ファイル選択。
もし、それ=ダイアログキャンセルの値なら、戻る。
a=(その、アイテム)
a#1#(その、値)=それ
aの、「\n,\n」を、「」に、置換
その、アイテムは、それ
要素数((その、アイテム))
もし、(その、値)<(それ-2)なら、(その、値は、(その、値)+1)
a=「」
戻る。
＊アイテム削除
(イベントオブジェクトの、名前)の、『削除ボタン』を、グリッドに、置換。
その単語に特定。
もし、((その、値)<0)なら、戻る。
a=(その、アイテム)
a#1#(その、値)=「」
aの、「\n,\n」を、「」に、置換
その、アイテムは、それ
a=「」
戻る。
＊アイテム上へ
(イベントオブジェクトの、名前)の、『上へボタン』を、グリッドに、置換。
その単語に特定。
もし、((その、値)<2)なら、戻る。
a=(その、アイテム)
b=a#1#(その、値)
a#1#(その、値)=(a#1#((その、値)-1))
a#1#((その、値)-1)=b
aの、「\n,\n」を、「」に、置換
その、アイテムは、それ
a=「」
戻る。
＊アイテム下へ
(イベントオブジェクトの、名前)の、『下へボタン』を、グリッドに、置換。
その単語に特定。
要素数((その、アイテム))
もし、((その、値)<0)または((その、値)>(それ-3))なら、戻る。
a=(その、アイテム)
b=a#1#(その、値)
a#1#(その、値)=(a#1#((その、値)+1))
a#1#((その、値)+1)=b
aの、「\n,\n」を、「」に、置換
その、アイテムは、それ
a=「」
戻る。
＊アイテムクリア
「設定を破棄します。\nよろしいですか。」と、二択。
もし、それ<>1なら、戻る。
(イベントオブジェクトの、名前)の、『クリアボタン』を、グリッドに、置換。
その単語に特定。
「その、アイテムは、{その、名前}初期アイテム」を、ひまわりする。
戻る。
＊グリッドイベント
a=イベントオブジェクトの、アイテム
b=(イベントオブジェクトの、値)-1
c=行数(a)-2-b
d=行数(イベントの値)
もし、d>cなら、(
ステータスエディタは、「設定に失敗しました：アイテム数オーバー」
BEEP。戻る。
)
イベントの値を、反復(a#1#(b+回数)=それ)
aの、「\n,\n」を、「」に、置換
イベントオブジェクトの、アイテムは、それ
a=「」
戻る。
＊アイテム選択
a=イベントオブジェクトの、アイテム
b=イベントオブジェクトの、値
もし、((a#1#b)=「」)なら、戻る。
(a#1#b)から、ファイル名を切り出す。
拡張子を切り出す。
「.」を、「」に、置換。
対応画像形式の中で、それが、何文字目。
もし、それ<1なら、(BEEP。戻る。)
イメージの、画像は、(a#1#b)
高さラベルの、位置は、イメージの、下側。
その、テキストは、「{イメージの、高さ} x {イメージの W}」。
プレビューフォームの、可視は、オン。
戻る。
＊簡易ヘルプイベント
もし、戻るフラグ=1なら、戻る。
「ステータスエディタは、{イベントオブジェクトの、名前}ヘルプ」を、ひまわりする。
戻る。
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
※※※※※※※※ ※※※※※※※※※
※※※※※※ 設定フォームのイベント ※※※※※※※
※※※※※※※※ ※※※※※※※※※
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
＊設定決定イベント
もし、戻るフラグ=1なら、戻る。
戻るフラグ=1
設定フォームの、可視は、オフ。
もし、イベントオブジェクト<>「決定」なら、(設定読み込み。母艦背景。戻る。)
もし、名前エディタ=「」なら、(
名前エディタは、作者名。
)
iniファイルを、開く。
もし、それ=「{名前エディタ}\n{メアドエディタ}\n{アドレスエディタ}
{対応画像形式}\n{対応圧縮形式}\n{基本フォルダエディタ}
{文字サンプルラベルの、背景色}\n{背景サンプルラベルの、背景色}
{画像ファイルを使用チェック}\n{画像ファイルエディタ}\n{配置ラジオ}」なら、戻る。
戻るフラグ=0
設定書き込み
設定読み込み
母艦背景
戻るフラグ=1
戻る。
＊画像選択イベント
「画像ファイル(*.ico,*.jpg,*.png,*.bmp)|*.ico;*.jpg;*.png;*.bmp|」&
「JPGファイル(*.jpg)|*.jpg|PNGファイル(*.png)|*.png|」&
「BMPファイル(*.bmp)|*.bmp|ICOファイル(*.ico)|*.ico|全てのファイル(*.*)|*.*」の、読込ファイル選択。
もし、それ=ダイアログキャンセルの値なら、戻る。
画像ファイルエディタは、それ。
戻る。
＊画像ファイルチェックイベント
もし、戻るフラグ=1なら、戻る。
「画像ファイルエディタ\n画像選択ボタン\n配置ラジオ」を、
反復(
「{それ}の、有効は、画像ファイルを使用チェック」を、ひまわりする。
)
戻る。
＊色選択イベント
(イベントオブジェクトの、名前)の、「選択ボタン」を、「サンプルラベル」に、置換。
その単語に特定。
色選択。
もし、それ=ダイアログキャンセルの値なら、戻る。
その、背景色は、それ。
戻る。
＊拡張子初期化イベント
(拡張子コンボの、テキスト)の、『利用可能な』を、『対応』に、置換。
a=それ
(拡張子コンボの、テキスト)の、『利用可能な』を、『初期』に、置換。
「それ={それ}」を、ひまわりする。
「{a}=それ」を、ひまわりする。
「,」で、区切る。
拡張子リストの、アイテムは、それ。
戻る。
＊拡張子追加イベント
もし、拡張子エディタ=「」なら、戻る。
「{拡張子リストの、アイテム}{拡張子エディタ}\n」の、0列目をキーに、表重複項目削除。
拡張子リストの、アイテムは、それ。
拡張子エディタ=「」
(拡張子コンボの、テキスト)の、『利用可能な』を、『対応』に、置換。
a=それ
(拡張子リストの、アイテム)の、「\n」を、「,」に、置換。
「{a}=それ」を、ひまわりする。
戻る。
＊拡張子削除イベント
それ=拡張子リストの、アイテム
行数。
もし、((拡張子リストの、値)<0)、または、(それ<2)なら、戻る。
(拡張子コンボの、テキスト)の、『利用可能な』を、『初期』に、置換。
「それ={それ}」を、ひまわりする。
「,」で、区切る。
a=それ
それ=拡張子リストの、アイテム
(拡張子リストの、値)行目を、行削除。
a&それの、0列目をキーに、表重複項目削除。
拡張子リストの、アイテムは、それ。
(拡張子コンボの、テキスト)の、『利用可能な』を、『対応』に、置換。
a=それ
(拡張子リストの、アイテム)の、「\n」を、「,」に、置換。
「{a}=それ」を、ひまわりする。
戻る。
＊拡張子ヘルプイベント
もし、((イベントオブジェクトの、名前)=元オブジェクト)なら、戻る。
「それ={イベントオブジェクトの、名前}ヘルプ」を、ひまわりする。
「,」で、区切る。
拡張子ヘルプラベルの、テキストは、それ。
元オブジェクト=イベントオブジェクトの、名前
戻る。
＊拡張子コンボイベント
(拡張子コンボの、テキスト)の、『利用可能な』を、『対応』に、置換。
「それ={それ}」を、ひまわりする。
「,」で、区切る。
拡張子リストの、アイテムは、それ。
戻る。
＊基本フォルダ設定イベント
「」の、フォルダ拡張選択。
もし、それ=ダイアログキャンセルの値なら、戻る。
基本フォルダエディタは、それ。
戻る。
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
※※※※※※※※ ※※※※※※※※※
※※※※※※※ メニューのイベント ※※※※※※※※
※※※※※※※※ ※※※※※※※※※
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
＊ヘルプメニューイベント
ヘルプファイルを、起動。
戻る。
＊新規イベント
「現在の設定を破棄します。\nよろしいですか？」と、二択。
もし、それ=1なら、(
「メニュー\nタブ」を、反復(
「{それ}グリッドの、アイテムは、{それ}グリッド初期アイテム」を、ひまわりする。
)
)
戻る。
＊設定メニューイベント
設定フォームの、可視は、オン。
母艦の、有効は、オフ。
＊ミハルくん
もし、((設定フォームの、可視)=0)なら、(
設定決定イベント。
戻るフラグ=0。
母艦の、有効は、オン。
戻る。
)
0.1秒、待つ。
ミハルくんに、飛ぶ。
＊ヘルプファイルの作成
母艦のパス&「help\\」が、存在。
もし、それ=0なら、母艦のパス&「help\\」へ、フォルダ作成
『
スキン作成支援キット ヘルプ
スキン作成支援キット ヘルプ
このソフトはひまわりエディタのスキン作成を支援するソフトです。
使い方
-
はじめて起動するとダイアログが出ますので指示に従って記入してください。
名前以外は空白でも大丈夫です。
-
グリッド部分に使いたい画像をドロップしてください。
複数ドロップした場合は選択項目から順に設定されます。
項目数よりドロップファイルが多いと設定は失敗します。
設定した項目を選択するとプレビューされます。
ボタンについてはマウスオーバーで(偽)ステータスバーに簡単な説明が表示されるのでそれを参照してください。
-
「作成」とかいてあるボタンを押すとインストーラを作成します。
数が足りなくても、幅の合計が高さの10倍・12倍あればちゃんと作成されます。
作成に失敗すると(偽)ステータスバーにエラーメッセージが出ます。
設定について
メニューから「設定」を選ぶといろいろな設定ができます。
基本設定
作者名・メールアドレス・Webアドレスの設定ができます。
画像の基本フォルダはダイアログから画像を設定する時に最初に表示するフォルダを設定できます。
拡張子設定
プラグインで使える拡張子が増えている場合、ここで設定すると対応形式が増えます。
コンボで対応形式を増やしたいファイルの種類を選び、エディタに拡張子を記入後、Enterキーまたは＋ボタンでエディタに書いた拡張子が使えるようになります。
適当に増やすと処理が重くなったりエラーが出たりするので分からない場合はそのままにしておきましょう。
インターフェイス
インターフェイスの設定をします。文字色・背景色等の設定ができます。
「画像ファイルを使用」をオンにして画像ファイルを設定しておくと背景に画像を表示することができます。
』を、ヘルプファイルに、保存。
戻る。